4.6/5 - (44 امتیاز)
در این مطلب نحوه استفاده از تابع match را به همراه مثال های فرمولی ارائه خواهیم کرد. همچنین نحوه بهبود فرمول های جستجوگر خود را با ترکیب تابع match و vlookup نشان خواهیم داد.

در اکسل، توابع جستجوگر متعددی وجود دارد. که میتوانند شما را در پیدا کردن یک مقدار در محدوده ای از سلول ها کمک کنند. و تابع match یکی از این توابع است. اساساً این تابع جایگاه یک آیتم را در محدوده ای از سلول ها مشخص می کند. ولی این تابع میتواند بسیار فراتر از این کار فعالیت کند.

تابع match در اکسل – ترکیب و کاربرد

تابع match در اکسل در محدوده ای از سلول ها یک مقدار مشخص شده را جستجو میکند. و جایگاه نسبی آن مقدار را برمیگرداند.

ترکیب تابع match به شکل زیر است:

=MATCH(lookup_value,lookup_array,[match_type])

Lookup_value(الزامی): مقداری که میخواهید پیدا کنید. این مقدار میتواند عدد، متن، آدرس سلول یا مقدار منطقی باشد.

Lookup_array(الزامی): محدوده ای از سلول ها که عمل جستجو در این محدوده انجام میشوند.

Match_type(اختیاری): نوع مطابقت را مشخص میکند. این مقدار میتواند 0,1,-1 باشد. وقتی این پارامتر را 0 قرار دهید مطابقت دقیق، و دو مقدار دیگر مطابقت جزئی را جستجو میکنند.

  • 1 یا خالی(پیش فرض) بزرگترین مقدار موجود در آرایه را که کوچکتر با مساوی مقدار مورد جستجو باشد را یافت میکند. در صورت انتخاب این مقدار می بایست Lookup_array را به صورت صعودی مرتب کرد یعنی از کوچکتر به بزرگتر و از a تا z
  • 0: اولین مقداری را که در آرایه با مقدار مورد جستجو برابر باشد را برمیگرداند. در این مورد مرتب کردن آرایه لازم نیست.
  • 1-: کوچکترین مقدار در آرایه را که بزرگتر یا مساوی مقدار مورد جستجو باشد را برمیگرداند. در این حالت می بایست داده های موجود در Lookup_array را به صورت نزولی و برعکس مورد اول مرتب کرد.

مثالی از تابع MATCH برای درک بهتر این تابع

نام دانش آموزان در ستون A و نمرات آنان در ستون B قرار گرفته است. و اطلاعات از بزرگتر به کوچکتر مرتب شده است. برای پیدا کردن جایگاه یک دانش آموز ( برای مثال علی) میتوان از فرمول زیر استفاده کرد:

=match("علی",A2:A8,0)

تابع match در اکسل – ترکیب و کاربرد

همچنین میتوانید مقدار مورد جستجو را در یک سلول مثلاً e1 قرار دهید. و آدرس سلول را وارد فرمول کنید:

=match(E1,A2:A8,0)

تابع match در اکسل – ترکیب و کاربرد

همانطور که در تصویر بالا مشاهده میکنید، نام دانش آموزان به صورت تصادفی وارد سلول ها شده و ترتیبی برای آن اتخاذ نشده است. در نتیجه از 0 برای پارامتر سوم تابع خود استفاده میکنیم. زیرا فقط این نوع مطابقت نیازی به مرتب کردن داده ها ندارد. به صورت فنی تابع MATCH جایگاه «علی» را مشخص میکند. ولی از آنجایی که نمرات به صورت نزولی مرتب شده است، فقط مشخص میکند که علی به لحاظ بهترین نمرات کلاس در جایگاه چهارم قرار دارد.

اگر در هنگام کار با تابع match با خطای #N/A مواجه می شوید، در اینجا سه دلیل عمده ای که این خطا ایجاد می شود و روش های حل آن را بررسی کرده ایم:

خطای #N/A در توابع اکسل و روش ها حل آن

4 چیزی که می بایست در مورد تابع MATCH بدانید:

همانطور که مشاهده کردید، استفاده از تابع MATCH در اکسل کار ساده ای است. ولی مثل دیگر توابع این تابع نیز دارای توضیحاتی است که می بایست از این توضیحات آگاهی داشته باشید:

  1. تابع MATCH جایگاه یک مقدار را در یک آرایه برمیگرداند نه خود مقدار را.
  2. تابع MATCH نسبت به حروف بزرگ و کوچک حساس نیست. به این معنی که استفاده از حروف بزرگ و کوچک هیچ فرقی ندارد.
  3. در صورت که در آرایه مورد جستجو چند مقدار look up value به صورت تکراری وجود داشته باشد، جایگاه اولین مقدار برگردانده میشود.
  4. در صورتی که مقدار مورد جستجو یافت نشود تابع MATCH خطای #N/A را برمیگرداند.

فیلم های آموزشی تابع MATCH

در این آموزش قصد داریم شما را با تابع match در اکسل آشنا کنیم و با یک مثال کاربردی نحوه استفاده از این تابع مهم رو آموزش بدیم. به صورت کلی زمانی از match استفاده می کنیم که بخواهیم یک مقداری رو در یک بازه، مکانش رو پیدا کنیم.

پیشنهاد مطالعه: 

تابع xlookup در اکسل بسیاری از محدودیت های تابع vlookup را حل کرده است، همچنین یک جایگزین مناسب برای ترکیب تابع index و match است، این مطلب رو حتما مطالعه کنید و با تابع xlookup بیشتر آشنا بشید:

تابع xlookup در اکسل (تایع جدید در اکسل 2021)

مثلا فرض کنید داده های منابع شعب یک بانک برای روز های مختلف در یک جدول ذخیره میشه. حالا میخواید ببینید تفاضل منابع بین دو تاریخ به چه میزان هست.

با استفاده از vlookup شعبه و با استفاده از match ستون تاریخ مورد نظر رو پیدا می کنید.

اگر در هنگام کار با تابع match با خطای #N/A مواجه می شوید، در اینجا سه دلیل عمده ای که این خطا ایجاد می شود و روش های حل آن را بررسی کرده ایم:

خطای #N/A در توابع اکسل و روش ها حل آن

در ویدیو زیر قصد داریم یک کاربرد دیگر از تابع match بپردازیم.

فرض کنید شما یک پرسش نامه یا یک تحقیق بازار یا یک فرم کنترل محصول دارید. داده ها به صورت اعداد 1 تا 10 برای پرسش های مختلف جمع آوری می شوند و در فایل اکسل قرار میگیرند. اگر بخواهیم بدون تغیر در فایل برای گزارش گیری از لیبل های مختلف (مثلا: خیلی خوب، خوب، متوسط و …) استفاده کنیم و کاربر با اعداد درگیر نباشد، از چه چه راهکاری استفاده کنیم؟

برای این کار راهکارهای متفاوتی می تواند مورد استفاده قرار گیرد. در قسمت قبل گفتیم تابع match مکان یک مقدار در یک بازه (ارایه) را مشخص می کند. برای حل این مسئله از همین روش استفاده خواهیم کرد.

نحوه استفاده از MATCH در اکسل –  مثال های فرمولی

حال که با کاربردهای اولیه تابع MATCH آشنا شدید، به بررسی چند مثال فرمولی پیشرفته تر میپردازیم.

تابع MATCH همراه با کاراکتر های wildcard

شبیه به بسیاری از دیگر توابع اکسل، از کاراکترهای زیر در ترکیب با تابع MATCH نیز میتوان استفاده کرد:

  • علامت سوال(؟)
  • علامت ستاره(*)

نکته: این کاراکترها تنها در صورتی در تابع MATCH قابل استفاده هستند که نوع مطابقت بر روی 0 قرار داده شده باشد.

از کاراکترهای wildcard زمانی استفاده میشود که میخواهید جایگاه چند کاراکتر یا قسمتی از یک رشته را پیدا کنید. برای درک بهتر، به مثال زیر توجه کنید:

فرض کنید لیستی از فروشندگان منطقه ای و مقدار فروش آنها برای ماه قبل را در اختیار دارید. و میخواهید جایگاه نسبی یک فروشنده را در میان لیست فروشندگان (بر اساس مقدار فروش و به صورت نزولی مرتب شده است) پیدا کنید. ولی شما نام این فروشنده را به صورت دقیق به یاد نمی آورید ولی چند کاراکتر ابتدای آن را به خاطر دارید.

فرض کنید لیست فروشندگان در سلول های A2:A11 قرار دارد و در جستجوی نامی هستید که با «امی» شروع میشود. فرمول به شکل زیر خواهد شد:

=match("امی*",A2:A11,0)

برای فراگیر تر کردن فرمول خود میتوانید lookup value را در یک سلول تایپ کنید و آن سلول را به کاراکترهای wild card متصل کنید:

=match(E1&"*",A2:A11,0)

تابع MATCH همراه با کاراکتر های wildcard

همانطور که در تصویر زیر نشان داده است، فرمول مقدار 3 را برمیگرداند که محل« امیر» را نشان میدهد.

برای جایگزین کردن یک کاراکتر در lookup value میبایست از علامت سوال استفاده کرد. برای مثال:

=match("ba?er",A2:A11,0)

تابع MATCH همراه با کاراکتر های wildcard

فرمول بالا نام baker را پیدا میکند و جایگاه نسبی آن را برمیگرداند که 5 است.

فرمول match حساس به حروف بزرگ و کوچک

همانطور که در ابتدای این مطلب ذکر شد، تابع MATCH بین حروف بزرگ و کوچک تمایزی قائل نمیشود. برای حساس کردن این تابع در مورد حروف بزرگ و کوچک، ار ترکیب تابع MATCH و exact استفاده کنید. این تابع کلمات را دقیقاً با هم مقایسه میکند و بزرگ و کوچک بودن حروف را نیر مورد نوجه قرار میدهد:

=match(true,exact(lookup array,lookup value),0)

این فرمول با منطق زیر کار میکند:

  • تابع exact مقدار lookup value را با تک تک عناصر موجود در آرایه مورد مقایسه قرار میدهد. در صورتی که یکی از سلول ها دقیقاً مشابه مقدار مورد جستجو باشد، تابع true را برمیگرداند در غیر اینصورت false برگردانده میشود.
  • آنگاه تابع MATCH مقدار true(که همان lookup value است) را با هرکدام از مقادیر آرایه ای که توسط تابع exact برگردانده شده است مقایسه میکند و محل اولین مقدار مورد تطابق را برمیگرداند.

لطفاً به یاد داشته باشید که این فرمول یک فرمول آرایه است و می بایست حتماً از کلید های ترکیبی Ctrl + Shft + Enter استفاده کنید.

با فرض اینکه مقدار مورد جستجوی شما در سلول E1 قرار گرفته و آرایه جستجوی شما A2:A9 است، فرمول به شکل زیر خواهد بود:

=match(true,exact(A2:A9,E1),0)

تصویر زیر نتیجه فرمول match حساس به حروف بزرگ و کوچک را نشان میدهد:

فرمول match حساس به حروف بزرگ و کوچک

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

مقایسه دو ستون یکی از رایج ترین کارهایی است که در اکسل انجام میشود و میتوان این کار را به شیوه های مختلفی انجام داد. یکی از این شیوه ها استفاده از isna/match است:

=IF(ISNA(MATCH(1st value in list1,list2,0)),"در لیست 1 نیست","")

برای هر مقداری از لیست 2 که در لیست 1 موجود نیست، فرمول مقدار “درلیست 1 نیست” را برمیگرداند. شیوه کار این فرمول در زیر توضیح داده شده است:

  • تابع MATCH یک مقدار از لیست 1 را در لیست دو جستجو میکند. در صورتی که یافت شود، جایگاه آن را برمیگرداند و اگر یافت نشود مقدار #n/a برگردانده میشود.
  • تابع isna فقط یک کار را در اکسل انجام میدهد.خطای #n/a را جستجو میکند اگر یک مقدار خطای n/a باشد true را برمیگرداند در غیر این صورت false را برمیگرداند. در مثال ما true به این معنی است که یک مقدار که در لیست 1 وجود دارد در لیست 2 وجود ندارد.
  • از آنجایی که مقدار true برای مقادیری که در لیست 2 یافت نشده است ممکن است کمی برای کاربران شما گیج کننده باشد، از تابع if استفاده میکنیم تا به جای آن مقدار “در لیست 1 نیست” یا هر متنی که شما میخواهید را برگرداند .

با فرض اینکه مقادیر ستون A را با مقادیر ستون B مقایسه میکنید، فرمول به شکل زیر میشود (سلول B2 بالاترین سلول است):

=IF(ISNA(MATCH(B2,A:A)),"در لیست 1 نیست","")

همانطور که گفتیم تابع MATCH به خودی خود نسبت به حروف بزرگ و کوچک حساس نیست. برای حساس کردن این تابع، از تابع excat در آرایه جستجو خود استفاده کنید. و به یاد داشته باشید که کلیدهای ترکیبی Ctrl + Shift + Enter را فشار دهید.

=IF(ISNA(MATCH(true,exact(A:A,B2),0)),"در لیست 1 نیست","")

تصویر زیر هر دو فرمول را به صورت عملی نشان میدهد:

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

توابع vlookup و match در اکسل

در این مثال فرض شده است که شما اطلاعات پایه ای در مورد تابع vlookup دارید. اگر اینطور باشد، حتماً در مورد محدودیت های این تابع نیز اطلاع دارید و به دنبال یک جایگزین قویتر برای این تابع هستید.

تابع vlookup در اکسل | مثال ها و کاربردها

معرفی تابع match در اکسل، ترکیب vlookup و match در محاسبات بانکی-توابع اساسی اکسل

یکی از بزرگترین محدودیت های این تابع این است که اگر ستون جدید را اضافه کنید یا یکی از ستون ها را حذف کنید تابع از کار می افتد. این اتفاق به این دلیل می افتد که تابع Vlookup مقدار مورد نظر را بر اساس شماره ستونی که در index num مشخص میکنید برمیگرداند. از آنجایی که index num در درون فرمول قرار گرفته و امکان تغییر در آن وجود ندارد، زمانی که یک ستون اضافه میشود یا یکی از ستون ها حذف میشود اکسل قادر به به تغییر این پارامتر نیست.

تابع match در اکسل با جایگاه نسبی lookup value کار میکند و این تابع برای تعیین col_index_num تابع vlookup بسیار مناسب است. به عبارت دیگر، به جای قرار دادن یک عدد برای شماره ستون، میتوانید تابع match را برای بدست آوردن محل ستون مورد نظر استفاده کنید.

برای درک بهتر این موضوع یکبار دیگر جدول دانش آموزان و نمرات آنها را مورد توجه قرار دهید، ولی اینبار نمرات واقعی را و نه جایگاه نمرات را در آرایه به دست میآوریم.

با فرض اینکه lookup value در سلول F1 قرار دارد، table array عبارت است از $A$1:$C$2 ( بهتر است اگر میخواهید فرمول خود را به سلول دیگر ی کپی کنید از آدرس مطلق استفاده کنید)، و فرمول به شکل زیر میشود:

(VLOOKUP(F1, $A$1:$C$8, 3, FALSE=

پارامتر سوم(col_index_num)، 3 قرار داده شده است زیرا «نمره ریاضی» که مورد نظر ماست در سومین ستون جدول قرار دارد. همانطور که در تصویر زیر مشاهده میکنید، یک فرمول vlookup معمولی خوب کار میکند:

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

ولی زمانی که یک ستون را حذف یا اضافه کنید اتفاق دیگری می افتد:

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

چرا خطای #ref اتفاق می افتد؟ زیرا(col_index_num) که بر روی 3 قرار داده شده است، به اکسل می گوید که ستون سوم را برگرداند، در حالی که فقط 2 ستون در جدول وجود دارد.

برای جلوگیری از اتفاق افتادن چنین مسئله ای، می توانید با قرار دادن فرمولی  شبیه به فرمول زیر تابع vlookup خود را پویا تر کنید:

=match(E2,A1:C1,0)
  • E2 مقدار lookup value است که دقیقاً مشابه نام return col است (ستونی که میخواهید مقدار مورد نظر از آن برگردانده شود. در این مثال نمره ریاضی).
  • A1:C1 آرایه جستجو است که سرفصل جدول را نیز در بر میگیرد.

حال، این تابع MATCH را در درون پارامتر col_index_num تابع vlookup  خود قرار دهید. مثل:

=vlookup(F1,$A$1:$C$8,match(E2,$A$1:$C$1,0),false)

و مطمئن باشید که با حذف یا اضافه کردن هر تعداد ستون این فرمول بدون نقص کار خواهد کرد.

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

در تصویر بالا همه آدرس های سلول ها را ثابت کردیم تا در صورت کپی کردن فرمول به هر سلول دیگری یا حتی هر ورک بوک دیگری فرمول تغییر نکند. همانطور که در تصویر زیر مشاهده میکنید. بعد از اینکه یک ستون را حذف کردیم فرمول به خوبی کار میکند. علاوه بر این ، اکسل بسیاری باهوش است و آدرس های مطلق را به خوبی در این مورد تغییر میدهد.

مقایسه دو ستون به لحاظ مطابقت ها و تفاوت ها(isna match)

توابع hlookup و match در اکسل

به همین شیوه، میتوانید برای بهبود تابع hlookup خود نیز از تابع match استفاده کنید. اصول اساسی همانی است که در مورد Vlookup استفاده کردیم. از تابع match برای بدست آوردن محل نسبی return column استفاده می کنید. و مقدار بدست آمده را در row index num تابع hlookup خود قرار میدهید.

فرض کنید مقدار lookup value در سلول B5 قرار دارد و آرایه جستجو B1:H3 است. نام return row در سلول A6 قرار گرفته و header های ردیف در A1:A3 قرار دارند. فرمول کامل به شکل زیر است:

=hlookup(B5,B1:H3,match(A6,A1:A3,0),false)

توابع hlookup و match در اکسل

همانطور که مشاهده کردید، تابع match میتواند تا حد زیادی به بهبود توابع hlookup و vlookup منجر شود. با اینحال، تابع match نمیتواند تمام محدودیت های این توابع را رفع کند. برای مثال فرمول vlookup هنوزه قادر نیست سمت چپ خود را جستجو کند. و تابع hlookup هیچ ردیفی به جز بالاترین ردیف را قادر به جستجو کردن نیست.

برای رفع این نوع محدودیت ها، میتوانید از ترکیب توابع index و match استفاده کنید. که در بسیاری از موارد و زمینه ها از توابع hlookup و vlookup قوی تر هستند. برای دسترسی به جزئیات و مثال های متعدد فرمولی میتوانید به «چرا ترکیب توابع index و match بهتر از تابع vlookup است؟» مراجعه کنید.

شیوه استفاده از فرمول های match در اکسل توضیح داده شد. امیدواریم مثال های توضیح داده شده در این مطلب، در زمینه شغلی شما نیز کارایی داشته باشد.

از اینکه این مطلب را مطالعه کردید متشکریم.

مشترک شدن
Notify of
guest

55 نظرات
نظردهی درون متنی
مشاهده همه نظرات
کیمیا خواجویی نژاد

سلام وقت بخیر من 2 تا فایل اکسل دارم که 1 فایل اسامی و آدرس کامل داره و یک فایل اسامی داره ولی آدرس ها ناقصه میخوام فایل کاملو جایگزین کنم طبق اسامی آدرسهای درست جایگزین شه باید از چه تابعی استفاده کنم؟

امیر دایی

سلام
اول باید با استفاده از تابع vlookup در اکسل به ازای هر اسم ادرس رو در ستون مقابلش بیارید.

ندا محبوب

وقت بخیر
من 2 تا اکسل دارم که یکسری اسامی مشابه دارم برای مثال
هتل lara keme antalya در یک اکسل
lara keme در اکسل دیگر
به چه صورت میتونم اینارو یکسان سازی کنم ؟ و دیتا ها مورد نظرم بچینم

امیر دایی

راه اولش در صورتی که تعداد دیتا کم هست این هست که یه لیست یونیک از اسامی فایلی که تعداد یونیکش بیشتر هست درست کنید و معادل اون مقدارها رو در فایل معادل پیدا کنید و جلوش بذارید و بعد با توابع vlookup یا …. یکسان سازی رو انجام بدید. راه دوم که دقت کمتری داره می تونید از قابلیت fuzzy lookup استفاده کنید. می تونید دانلود افزونش رو توی گوگل سرچ کنید و دانلودش کنید. با این افزونه می تونید با تقریب مورد نظر مقدارهای مشابه رو پیدا کنید. راه سوم استفاده از قابلیت fuzzy merge در پاور کوئری… مطالعه بیشتر »

علیرضا

مطلب جامع و عالی در باره match بود، مثال هایی هم که برای تابع match داشتید بسیار عالی بود.

امیر دایی

خواهش میکنم. موفق باشید.

مرتضی

با سلام در یک شیت کلیه پرداختی های قسطی تمام مشتری ها رو دارم و در شیت دیگر میخوام وقتی اسم یک مشتری رو میزنم تمام پرداختی های اون رو نشون بده به نظرتون چی کار کنم؟

امیر دایی
محسن

سلام در یک سری سلول یه متن هست می خوام از سمت چپ شروع کنه استخراج به اولین عدد که رسید متوقف بشه یعنی :
فاکتور مشتری@داخلی فروش12 نادر یعقوبی
تبدیل بشه به
نادر یعقوبی

امیر دایی

سلام
اگر دقیقا بخواید با همین منطقی که گفتید اسم ها رو استخراج کنید باید از برنامه نویسی vba استفاده کنید.
ولی می تونید به مسئله با دید دیگه ای هم نگاه کنید.
مثلا اگر همیشه این اسم بعد از داخلی فروش(عدد) هست. با تابع find کلمه داخلی فروش رو پیدا کنید. و بعد از این کلمه اولین space رو جستجو کنید. اینطوری به مکان space قبل از اسم میرسید و بعد اسم رو جدا کنید.

محسن

سلام
خیر تنها قانون ثابتی که هست اینه که بعد از عدد با یک فاصله اسم هست کدوم تابع هست که اولین عدد از سمت چپ رو می تونه پیدا کنه؟! در ضمن اعداد تا چهاررقمی هم هست

امیر دایی

برای پیدا کردن مکان آخرین عدد از فرمول زیر به صورت آرایه ای استفاده کنید: (بعد از وارد کردن فرمول به جای enter کلیدهای ctrl+shift+enter رو بزنید.)

=MAX(IF(ISNUMBER(VALUE(MID(A1,ROW(INDIRECT("1:" & LEN(A1))),1))),ROW(INDIRECT("1:" & LEN(A1)))))
محسن

سلام
افزونه Ablebits مثل آب خوردن حلش کرد!
از شما هم بینهایت ممنونم

هادی

سلام
من یک تابع لازم دارم که در یک سلول بهصورت کشویی باز شود و من از یک تا100 درصد را انتخاب کنم و پس از انتخاب درصد مورد نظر از لیست آن درصد از عدد جنس ورودی کسر و موجودی نمایش داده شود.مثلا
ورودی 1000 عدد
درصد حذف 5 درصد
پس از انتخاب درصد حذف مقدار باقیمانده کل در آن سلول نمایش داده شود

امیر دایی

سلام
این تابع نیست. یک فرمول ریاضی باید بنویسید.
من الان مشکل رو دقیق متوجه نشدم که توی ساخت لیست مشکل دارید یا فرمول ریاضی. اگر ساخت لیست رو مشکل دارید، ساخت لیست در اکسل رو توی گوگل سرچ کنید.
فرمول ریاضی که باید بنویسید با فرض اینکه تعداد در ستون A و درصد در ستون B باشه به شکل زیر هست:

=a2*(1-B2)
reza

سلام و خسته نباشید
یک لیست دارم که شامل چند شیت هستش و یک فایل دیگه هم دارم که به عنوان رفرنس می خوام استفاده کنم .یعنی در یک ستون بیام بر اساس اطلاعات فایل رفرنس و با استفاده از vlookup بطور اتومات داده ها را بنشونه . این کارو تونستم انجام بدم ولی به خاطر اینکه اطلاعات توی چند شیت با اطلاعات رفرنس تطابق کامل نداره ورود اطلاعات برای برخی از سل ها به هم میریزه . چیکار کنم ؟

امیر دایی

سلام
سه تا راه دارید:
1- در یک ستون جدید یا همون ستون در شیت ها داده ها رو یکسان کنید.
2- از قابلیت fuzzy match در پاور کوئری استفاده کنید. (کار vlookup رو انجام می ده با تعیین درصد شباهت)
3- از افزونه fuzzy lookup استفاده کنید.(کار vlookup رو انجام می ده با تعیین درصد شباهت)
استفاده از این ابزارهای مثل توابع نیست که با تغییر در مبدا، مقصد هم تغییر کنه. توی پاور کوئری باید رفرش انجام بدید توی افزونه باید مجدد فرایند رو تکرار کنید.

کیمیا

من میخوام یک جدول درست کنم و بالاش یک لیست کشویی بذارم که نام اشخاص باشه. میخوام وقتی از لیست کشویی نام یک نفر رو انتخاب میکنم و اطلاعات جدول رو پر کردم این اطلاعات به نام اون شخص ثبت شه. و وقتی دوباره از لیست یک نفر دیگر رو انتخاب میکنم جدول خالی باشه تا بتونم دوباره برای این نفر دیتا بریزم.

امیر دایی

برای این کار باید از Vba کمک بگیرید. یا اینکه روش ورود اطلاعات رو تغییر بدید.

mohsen

سلام استاد ، وقت به خیر …
توی قسمت مقایسه دو لیست با isna/match وقتی فرمول رو تو سلول مینویسم ، این فرمول برای سلول های بعد هم عمل مقایسه رو فقط برای سلول B2 انجام میده ، یعنی B2 پابت میمونه و تغییر نمیکنه ،علت چیه؟

امیر دایی

سلام
باید دقیقا توضیح بدید چی کار کردید تا بشه دلیلش رو متوجه شد. ولی احتمالا مشکل شما این هست که برای همه سلول ها یک فرمول رو نوشتید. باید فرمول برای سلول اول بنویسید و به سمت پایین درگ کنید تا آدرس ها به روز نسبی به روز بشه.

mohsen

تشکر استاد ، مشکل حل شد.

امیر دایی

خواهش میکنم موفق باشید

محسن

با سلام من یک لیست دارم از داده های روزانه و ماهانه چندین سال و میخوام مینیمم ماهیانه را محاسبه کنم نمیتونم. چون ستوان اول سال ستون دوم ماه و ستون سوم روز میباشد اعداد مختلف هم روبروی هر روز میباشد چطور مینیمم بگیرم به شط ثابت بودن ماه و سال؟؟؟؟؟؟؟؟/

امیر دایی

سلام از پیوت تیبل استفاده کنید.
ساخت پیوت تیبل در اکسل